Sage Quickstart for Linear Algebra¶

This Sage quickstart tutorial was developed for the MAA PREP Workshop “Sage: Using Open-Source Mathematics Software with Undergraduates” (funding provided by NSF DUE 0817071). It is licensed under the Creative Commons Attribution-ShareAlike 3.0 license (CC BY-SA).

Linear algebra underpins a lot of Sage’s algorithms, so it is fast, robust and comprehensive. We’ve already seen some basic linear algebra, including matrices, determinants, and the .rref() method for row-reduced echelon form in the Programming Tutorial, so the content here continues from there to some extent.

Left-Handed or Right-handed?¶

Sage “prefers” rows to columns. For example, the kernel method for a matrix \(A\) computes the left kernel – the vector space of all vectors \(v\) for which \(v \cdot A = 0\) – and prints out the vectors as the rows of a matrix.

Sage

sage: G = matrix(QQ, 2, 3, [[1,2,3],[2,4,6]])
sage: G.kernel()
Vector space of degree 2 and dimension 1 over Rational Field
Basis matrix:
[   1 -1/2]

Python

>>> from sage.all import *
>>> G = matrix(QQ, Integer(2), Integer(3), [[Integer(1),Integer(2),Integer(3)],[Integer(2),Integer(4),Integer(6)]])
>>> G.kernel()
Vector space of degree 2 and dimension 1 over Rational Field
Basis matrix:
[   1 -1/2]

Sage Live

G = matrix(QQ, 2, 3, [[1,2,3],[2,4,6]])
G.kernel()

Sage

sage: G.left_kernel()
Vector space of degree 2 and dimension 1 over Rational Field
Basis matrix:
[   1 -1/2]

Python

>>> from sage.all import *
>>> G.left_kernel()
Vector space of degree 2 and dimension 1 over Rational Field
Basis matrix:
[   1 -1/2]

Sage Live

G.left_kernel()

The right_kernel method computes the space of vectors \(w\) so that \(A \cdot w = 0\), of course.

Computations¶

Here are some more computations with matrices and vectors.

As you might expect, random matrices are random.

Sage

sage: H = random_matrix(QQ, 5, 5, num_bound = 10, den_bound = 4)
sage: H.det() # random
15416
sage: H.eigenvalues() # random
[-10.08361801792048?, -2.682220984496031?, 4.739405672111427?, -1.320116668180795? - 10.88676412262347?*I, -1.320116668180795? + 10.88676412262347?*I]

Python

>>> from sage.all import *
>>> H = random_matrix(QQ, Integer(5), Integer(5), num_bound = Integer(10), den_bound = Integer(4))
>>> H.det() # random
15416
>>> H.eigenvalues() # random
[-10.08361801792048?, -2.682220984496031?, 4.739405672111427?, -1.320116668180795? - 10.88676412262347?*I, -1.320116668180795? + 10.88676412262347?*I]

Sage Live

H = random_matrix(QQ, 5, 5, num_bound = 10, den_bound = 4)
H.det() # random
H.eigenvalues() # random

According to the Numerical analysis quickstart, the question marks indicate that the actual number is inside the interval found by incrementing and decrementing the last digit of the printed number. So 9.1? is a number between 9.0 and 9.2. Sage knows exactly what number this is (since it’s a root of a polynomial), but uses interval notation to print an approximation for ease of use.

The eigenvectors_right command prints out a list of (eigenvalue, [list of eigenvectors], algebraic multiplicity) tuples for each eigenvalue.

Sage

sage: H.eigenvectors_right() # random
[(-10.08361801792048?, [(1, -0.3820692683963385?, -0.4659857618614747?, -0.1264082922197715?, -0.3548156445133095?)], 1), (-2.682220984496031?, [(1, -1.855347152382563?, -0.4203899923232704?, 0.004411201577480876?, -0.5050698736445243?)], 1), (4.739405672111427?, [(1, 0.3284800982819703?, 2.059182569319718?, -1.428547399599918?, 0.5455069936349178?)], 1), (-1.320116668180795? - 10.88676412262347?*I, [(1, 0.710831790589076? + 0.2646474741698805?*I, 0.4504038344112447? + 3.145667601780920?*I, 2.763061217778457? + 0.9994136057023008?*I, 3.092272491890536? - 2.105461094305392?*I)], 1), (-1.320116668180795? + 10.88676412262347?*I, [(1, 0.710831790589076? - 0.2646474741698805?*I, 0.4504038344112447? - 3.145667601780920?*I, 2.763061217778457? - 0.9994136057023008?*I, 3.092272491890536? + 2.105461094305392?*I)], 1)]

Python

>>> from sage.all import *
>>> H.eigenvectors_right() # random
[(-10.08361801792048?, [(1, -0.3820692683963385?, -0.4659857618614747?, -0.1264082922197715?, -0.3548156445133095?)], 1), (-2.682220984496031?, [(1, -1.855347152382563?, -0.4203899923232704?, 0.004411201577480876?, -0.5050698736445243?)], 1), (4.739405672111427?, [(1, 0.3284800982819703?, 2.059182569319718?, -1.428547399599918?, 0.5455069936349178?)], 1), (-1.320116668180795? - 10.88676412262347?*I, [(1, 0.710831790589076? + 0.2646474741698805?*I, 0.4504038344112447? + 3.145667601780920?*I, 2.763061217778457? + 0.9994136057023008?*I, 3.092272491890536? - 2.105461094305392?*I)], 1), (-1.320116668180795? + 10.88676412262347?*I, [(1, 0.710831790589076? - 0.2646474741698805?*I, 0.4504038344112447? - 3.145667601780920?*I, 2.763061217778457? - 0.9994136057023008?*I, 3.092272491890536? + 2.105461094305392?*I)], 1)]

Sage Live

H.eigenvectors_right() # random

It may be more convenient to use the eigenmatrix_right command, which gives a diagonal matrix of eigenvalues and a column matrix of eigenvectors.

Sage

sage: D,P=H.eigenmatrix_right()
sage: P*D-H*P
[0 0 0 0 0]
[0 0 0 0 0]
[0 0 0 0 0]
[0 0 0 0 0]
[0 0 0 0 0]

Python

>>> from sage.all import *
>>> D,P=H.eigenmatrix_right()
>>> P*D-H*P
[0 0 0 0 0]
[0 0 0 0 0]
[0 0 0 0 0]
[0 0 0 0 0]
[0 0 0 0 0]

Sage Live

D,P=H.eigenmatrix_right()
P*D-H*P

Matrix Solving¶

We can easily solve linear equations using the backslash, like in Matlab.

Sage

sage: A = random_matrix(QQ, 3, algorithm='unimodular')
sage: v = vector([2,3,1])
sage: A,v  # random
(
[ 0 -1  1]
[-1 -1 -1]
[ 0  2  2], (2, 3, 1)
)
sage: x=A\v; x  # random
(-7/2, -3/4, 5/4)
sage: A*x  # random
(2, 3, 1)

Python

>>> from sage.all import *
>>> A = random_matrix(QQ, Integer(3), algorithm='unimodular')
>>> v = vector([Integer(2),Integer(3),Integer(1)])
>>> A,v  # random
(
[ 0 -1  1]
[-1 -1 -1]
[ 0  2  2], (2, 3, 1)
)
>>> x=A * BackslashOperator() * v; x  # random
(-7/2, -3/4, 5/4)
>>> A*x  # random
(2, 3, 1)

Sage Live

A = random_matrix(QQ, 3, algorithm='unimodular')
v = vector([2,3,1])
A,v  # random
x=A\v; x  # random
A*x  # random

For lots more (concise) information, see the Sage Linear Algebra Quick Reference.

Sage Quickstart for Linear Algebra¶

Matrices and Vectors¶

Left-Handed or Right-handed?¶

Vector Spaces¶

Computations¶

Matrix Solving¶